WD98: Sample Macro to Create Popup Toolbar

ID: Q185717

The information in this article applies to:

Microsoft Word 98 Macintosh Edition

SUMMARY

This article contains example Visual Basic for Applications code for macros that create a toolbar that contains a main menu, associated submenus, and assigned macros that run when you click a menu.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/

The following Visual Basic for Applications macro creates a toolbar named "My Toolbar," creates a main menu, submenus, and assigns a macro to run when the menus are clicked.

   Sub CreatePopupToolbarExample()

      Dim cbToolBar As CommandBar
      Dim cbMenuBar As CommandBarPopup
      Dim cbSuBMnu1 As CommandBarButton
      Dim cbSuBMnu2 As CommandBarPopup
      Dim cbSuBMnu2_PopUp As CommandBarButton
      Dim strToolBar As String
      Dim iCount As Integer

      ' Replace "My Toolbar" with a name
      ' you want to use for your toolbar.
      strToolBar = "My Toolbar"

      ' If a toolbar of this name already exists,
      ' append a number to the end of name to
      ' differentiate one from the other.
      For Each cbToolBar In CommandBars
         If Left$(cbToolBar.Name, Len(strToolBar)) = strToolBar Then
            iCount = iCount + 1
         End If
      Next

      If iCount > 0 Then strToolBar = strToolBar & iCount

      ' Create and display the Toolbar.
      Set cbToolBar = CommandBars.Add(Name:=strToolBar, _
         Position:=msoBarFloating)
      cbToolBar.Visible = True

      ' Create Main PopUp Menu on Toolbar.
      Set cbMenuBar = cbToolBar.Controls.Add(Type:=msoControlPopup)
      cbMenuBar.Caption = "Main Menu"

      ' Add a Menu Button and a Popup
      ' Menu to the "Main PopUp Menu."
      With cbMenuBar.Controls
         Set cbSuBMnu1 = .Add(Type:=msoControlButton)
         Set cbSuBMnu2 = .Add(Type:=msoControlPopup)
      End With

      ' Set properties for the sub
      ' button and popup menus.
      With cbSuBMnu1
         .Caption = "Sub Menu 1 (Button)"
         .Style = msoButtonCaption
         .OnAction = "ButtonAction1" ' <- Macro to run when clicked.
      End With
      With cbSuBMnu2
         .Caption = "Sub Menu 2 (Popup)"
      End With

      ' Add Popup menu to Sub Menu 2
      With cbSuBMnu2.Controls
         Set cbSuBMnu2_PopUp = .Add(Type:=msoControlButton)
      End With
      With cbSuBMnu2_PopUp
         .Caption = "Popup 1"
         .OnAction = "ButtonAction2" ' <- Macro to run when clicked.
      End With
   End Sub

When you click the menu item, one the following example macros will run (these macros are associated with the button items by the OnAction property):

   Sub ButtonAction1()
      MsgBox "Button Click."
   End Sub

   Sub ButtonAction2()
      MsgBox "Pop Up Button Click."
   End Sub

For more information about creating toolbars, from the Visual Basic Editor, click the Office Assistant, type "CommandBars," click Search, and then click Using Command Bars.

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q176476
   TITLE     : OFF: Office Assistant Not Answering Visual Basic Questions

REFERENCES

For additional information, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q181058
   TITLE     : OFF98: How to Run Sample Code from Knowledge Base Articles

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications

Additional query words: wordcon dropdown drop down combobox combo box submenu vba

Keywords          : kbdta kbdtacode OffVBA kbmacroexample macword98 
Version           : MACINTOSH:98
Platform          : MACINTOSH
Issue type        : kbhowto

Last Reviewed: April 7, 1999