ACC: Connecting to the First Available Network Drive (95/97)

ID: Q138904

The information in this article applies to:

Microsoft Access versions 7.0, 97

SUMMARY

Advanced: Requires expert coding, interoperability, and multiuser skills.

To make a network connection with the Windows application programming interface (API), you can use an unused logical drive letter or a Universal Naming Convention (UNC) name, such as \\Servername\Sharename. You can call the Windows API function, GetDriveType(), from a Visual Basic for Applications module to find the first available drive letter, and then make a network connection to this available drive.

This article assumes that you are familiar with Visual Basic for Applications and with creating Microsoft Access applications using the programming tools provided with Microsoft Access. For more information about Visual Basic for Applications, please refer to your version of the "Building Applications with Microsoft Access" manual.

MORE INFORMATION

To find the first free drive and make a network connection, follow these steps:

1. Create a module and type the following lines in the Declarations

   section:

      Option Explicit
      Declare Function GetDriveType Lib "kernel32" Alias "GetDriveTypeA" _
          (ByVal nDrive As String) As Long
      Declare Function WNetAddConnection Lib "mpr.dll" Alias _
          "WNetAddConnectionA" (ByVal lpszNetPath As String, _
          ByVal lpszPassword As String, ByVal lpszLocalName _
          As String) As Long

2. Type the following procedure:

      Public Function FreeDrive(MyShareName$, MyPWD$) As Integer
         On Local Error GoTo FreeDrive_Err
         Dim DriveNum As Long, FirstFreeDrive As String
         Dim FirstDrive As Long, Results As Long
         DriveNum = 2
         Do
            DriveNum = DriveNum + 1
            FirstFreeDrive = Chr$(DriveNum + 65) + ":\"
            FirstDrive = GetDriveType(FirstFreeDrive)
         Loop Until FirstDrive = 1
         FirstFreeDrive = Left(FirstFreeDrive, 2)
         FreeDrive = WNetAddConnection(MyShareName$, MyPWD$, _
          FirstFreeDrive)
      FreeDrive_End:
         Exit Function
      FreeDrive_Err:
         FreeDrive = Err
         MsgBox Error$
         Resume FreeDrive_End
      End Function

3. To test this function, type the following line in the Debug window,

   and then press ENTER

      ?FreeDrive(<"\\servername\sharename">, <"MyPwd">)

   where <\\servername\sharename> is a valid server and sharename in your
   network organization and <MyPwd> is your password that provides
   permission to the resource.

   NOTE: Some of the possible return values for the FreeDrive function
   include WN_SUCCESS, WN_NET_ERROR, and WN_BAD_PASSWORD. Other run-time
   errors could be returned from the function; therefore, error trapping
   should be implemented to handle any problems.

REFERENCES

For more information about declaring API functions, search for "Declare," and then "Declare Statement" using the Microsoft Access 97 Help Index.

For information about connecting to a network drive in Microsoft Access 1.x and 2.0, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q90861
   TITLE     : ACC: Connecting to the First Available Network Drive

Keywords          : kbprg
Version           : 7.0 97
Platform          : WINDOWS
Hardware          : x86
Issue type        : kbhowto

Last Reviewed: November 20, 1998