PPT97: Sample VB Code to Control Window Redraw

ID: Q166100

The information in this article applies to:

SUMMARY

This article shows how to use the LockWindowUpdate API function in the SetSmallCaps() macro to prevent PowerPoint from redrawing the application window. When the window is not locked you can see the fonts change as the macro runs. When the window is locked, this transition from normal text to small capital letters appears instantaneous. The macro unlocks the window before it finishes.

For more information about the SetSmallCaps() macro, please see the following article in the Microsoft Knowledge Base: 

   ARTICLE-ID: Q163694
   TITLE     : PPT: Sample Code to Apply Small Caps Formatting to
               Selection

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft Support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web: 

   http://www.microsoft.com/support/supportnet/refguide/default.asp

Overview of LockWindowUpdate() API Function

To use the LockWindowUpdate function, you must have a handle (HWND) to the window you want to lock. The sample code uses the FindWindow() API function

to obtain a handle to the main application window: 

   hwnd = FindWindow("PP97FrameClass", 0&)
If FindWindow() is successful, the variable hwnd (a long) holds a handle to the main application window. Now that you have a handle you can use the LockWindowUpdate() function to prevent that window from redrawing: 

   LockWindowUpdate (hwnd)
To unlock the window you must call LockWindowUpdate() with NULL (0&) as the parameter. 

   LockWindowUpdate (0&)
It is very important to add this statement. If your code locks a window and then fails to unlock it, the window stays locked even after your macro ends.

The Lock Window Version of the SetSmallCaps Macro

   ' API declarations for LockWindowUpdate() and FindWindow().
   Declare Function LockWindowUpdate Lib "user32" _
      (ByVal hwndLock As Long) As Long
   Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
      (ByVal lpClassName As String, ByVal lpWindowName As Long) As Long

   Sub SetSmallCaps()

      ' Used to trap errors.
      On Error Resume Next
      Err.Clear

      ' Dimension variables.
      Dim oTextRange As TextRange
      Dim oWordRange As TextRange
      Dim lNewFontSize As Long
      Dim i As Long
      Dim hwnd As Long

      ' Get a handle to the main application window.
      hwnd = FindWindow("PP97FrameClass", 0&)

      ' Lock the main applicationwindow. 
      ' Prevents PowerPoint from redrawing the main window.
      LockWindowUpdate (hwnd)

      ' Get reference to the selected text.
      Set oTextRange = ActiveWindow.Selection.TextRange

      ' Check if error occurred getting text selection.
      If Err.Number <> 0 Then

         MsgBox "Cannot apply Small Caps to selection. Please select " _
            & "some text and run the macro again.", vbExclamation, _
            "Invalid Selection"

         ' Stop the macro.
         End
      End If

      ' Loop through the words in the selection.
      For i = 1 To oTextRange.Paragraphs.Words.Count

         ' Get a reference to the first word in the selection.
         Set oWordRange = oTextRange.Paragraphs.Words(i, 1)

         'With oWordRange.Paragraphs.Characters(1, 1)
         With oWordRange.Characters(1, 1)

            ' Set the first letter to be upper case.
            .ChangeCase ppCaseUpper

            ' Calculate the new font size.
            lNewFontSize = ((.Font.Size) / 1.3)

         End With

         ' Change the remaining characters to the new font size.
         With oWordRange
            .Characters(2, (oWordRange.Length)).Font.Size = lNewFontSize
            .Characters(2, (oWordRange.Length)).ChangeCase ppCaseUpper
         End With

      Next i

      ' Unlocks the main application window. Whenever you use the
      ' LockWindowUpdate API to lock a window, you must call
      ' LockWindowUpdate again (with a Null parameter 0&) to allow the
      ' window to redraw.
      LockWindowUpdate (0&)

   End Sub

REFERENCES

For additional information, please see the following articles in the Microsoft Knowledge Base: 

   ARTICLE-ID: Q164735
   TITLE     : PPT97: Sample VB Code to Obtain Window Handle
For additional information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base: 

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications
Additional query words: 97 8.00 kbmacro ppt8 vba vbe 
Keywords          : kbcode kbmacro kbprg kbdta kbdtacode kbpptvba 
Version           : WINDOWS:97
Platform          : WINDOWS
Hardware          : x86
Issue type        : kbhowto

Last Reviewed: May 17, 1999