XL: VB Code to Automatically Set Min and Max Scale for Y-Axis

• Microsoft Excel 97 for Windows
• Microsoft Excel for Windows 95, version 7.0
• Microsoft Excel for Windows, versions 5.0, 5.0c
• Microsoft Excel for the Macintosh, versions 5.0, 5.0a
• Microsoft Excel 98 Macintosh Edition

SUMMARY

In Microsoft Excel, you can set the Minimum and Maximum properties of the y-axis scale to any value. The example in this article shows the steps necessary to create a Microsoft Visual Basic for Applications procedure that determines the minimum and maximum values contained in your data and sets the scale based on these values.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/default.asp

Type the following in a Visual Basic module sheet:

   Sub SetScaleToMinAndMaxValues()
      Dim ValuesArray(), SeriesValues As Variant
      Dim Ctr As Integer, TotCtr As Integer

      ' Uses the first chart on the active worksheet.
      With ActiveSheet.ChartObjects(1).Chart

         ' Note: Instead of the preceding line, you could use this line:
         '
         '    With ActiveChart
         '
         ' if you wanted to be able to run this macro on a chart sheet.

         ' Loops through all of the Series and retrieves the values
         ' and places them into an array named ValuesArray.
         For Each X In .SeriesCollection
            SeriesValues = X.Values
            ReDim Preserve ValuesArray(1 To TotCtr + UBound(SeriesValues))
            For Ctr = 1 To UBound(SeriesValues)
               ValuesArray(Ctr + TotCtr) = SeriesValues(Ctr, 1)

               ' In Excel 97 for Windows and Excel 98 Macintosh Edition, 
               ' change the preceding line of code to read as follows:
               '
               '    ValuesArray(Ctr + TotCtr) = SeriesValues(Ctr)

            Next
            TotCtr = TotCtr + UBound(SeriesValues)
         Next

         ' Reset the minimum and maximum scale to the minimum and
         ' maximum values in the ValuesArray.
         .Axes(xlValue).MinimumScaleIsAuto = True
         .Axes(xlValue).MaximumScaleIsAuto = True
         .Axes(xlValue).MinimumScale = Application.Min(ValuesArray)
         .Axes(xlValue).MaximumScale = Application.Max(ValuesArray)
      End With
   End Sub

Using the Macro

1. Select the worksheet that contains your chart.

2. To activate the macro, click Macro on the Tools menu, and run the SetScaleToMinAndMaxValues macro.

   In Excel 97 and Excel 98, click Tools, point to Macro, and then click Macros. Click SetScaleToMinAndMaxValues, and then click Run.

REFERENCES

"Visual Basic User's Guide," version 5.0, pages 145-146