XL: Visual Basic Example to Play an AVI File

ID: Q114039

The information in this article applies to:

Microsoft Excel for Windows, versions 5.0, 5.0c
Microsoft Excel for Windows 95, version 7.0
Microsoft Excel 97 for Windows

SUMMARY

It is possible to use Visual Basic for Applications to play an audio video interleaved (AVI) file from Microsoft Excel. You can reference an AVI file directly without inserting it as an object.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/

Microsoft Excel versions 7.0 and 97

In Microsoft Excel versions 7.0 and 97, the following Visual Basic Code plays a Microsoft AVI file at a specified location and size on the active window. This example assumes that the file Blastoff.avi file is stored in the default folder (C:\Winvideo). This code does not require the full Microsoft Video package in order to function properly.

Sample Code:

'API and Constant Declarations
'The function declarations must each be typed on one line.

Declare Function mciSendString Lib "winmm" Alias "mciSendStringA" (ByVal _
   lpstrCommand As String, ByVal lpstrReturnStr As Any, ByVal wReturnLen _
   As Long, ByVal hCallBack As Long) As Long

Declare Function GetActiveWindow Lib "USER32" () As Integer

Const WS_CHILD = &h40000000

Sub PlayAVIFile()

   'Dimension variables.
   Dim CmdStr As String, FileSpec As String
   Dim Ret As Integer, XLSHwnd As Integer

   'The name and location of the AVI file to play.
   FileSpec = "C:\WINVIDEO\BLASTOFF.AVI"

   'Get the active sheet's window handle.
   XLSHwnd = GetActiveWindow()

   'Opens the AVIVideo and creates a child window on the sheet
   'where the video will display. "Animation" is the device_id.
   CmdStr = ("open " & FileSpec & _
      " type AVIVideo alias animation parent " & _
      LTrim$(Str$(XLSHwnd)) & " style " & LTrim$(Str$(WS_CHILD)))

   Ret = mciSendString(CmdStr, 0&, 0, 0)

   'Put the AVI window at location 25, 120 relative to the
   'parent window (Microsoft Excel) with a size of 160 x 160.
   Ret = mciSendString("put animation window at 25 120 160 160", _
      0&, 0, 0)

   'The wait tells the MCI command to complete before returning
   'control to the application.
   Ret = mciSendString("play animation wait", 0&, 0, 0)

   'Close windows so they don't crash when you exit the application.
   Ret = mciSendString("close animation", 0&, 0, 0)

End Sub

Microsoft Excel versions 5.0 and 5.0c

In Microsoft Excel version 5.0, the following Visual Basic Code plays a Microsoft AVI file at a specified location and size on the active window. This example assumes Microsoft Video for Windows is installed and functioning properly with the BLASTOFF.AVI file stored in the default directory (C:\WINVIDEO). This code does not require the full Microsoft Video package in order to function properly. If the full package is not installed, the runtime module must be properly installed in its place for distribution, and the FileSpec variable must be modified accordingly.

Sample Code:

'API and Constant Declarations
'The function declarations must each be typed on one line.

Declare Function mciSendString Lib "MMSYSTEM" (ByVal lpstrCommand _
   As String, ByVal lpstrReturnStr As Any, ByVal wReturnLen As _
   Any, ByVal hCallBack As Any) As Long

Declare Function GetActiveWindow Lib "USER" () As Integer

Const WS_CHILD = &h40000000

Sub PlayAVIFile()

   'Dimension variables.
   Dim CmdStr As String, FileSpec As String
   Dim Ret As Integer, XLSHwnd As Integer

   'The name and location of the AVI file to play.
   FileSpec = "C:\WINVIDEO\BLASTOFF.AVI"

   'Get the active sheet's window handle.
   XLSHwnd = GetActiveWindow()

   'Opens the AVIVideo and creates a child window on the sheet
   'where the video will display. "Animation" is the device_id.
   CmdStr = ("open " & FileSpec & _
      " type AVIVideo alias animation parent " & _
      LTrim$(Str$(XLSHwnd)) & " style " & LTrim$(Str$(WS_CHILD)))

   Ret = mciSendString(CmdStr, 0&, 0, 0)

   'Put the AVI window at location 25, 120 relative to the
   'parent window (Microsoft Excel) with a size of 160 x 160.
   Ret = mciSendString("put animation window at 25 120 160 160", _
      0&, 0, 0)

   'The wait tells the MCI command to complete before returning
   'control to the application.
   Ret = mciSendString("play animation wait", 0&, 0, 0)

   'Close windows so they don't crash when you exit the application.
   Ret = mciSendString("close animation", 0&, 0, 0)

End Sub

For more information about the mciSendString function, see the "Microsoft Video for Windows Development Kit", and the Microsoft Visual Basic 3.0 help topic under Win SDK.

Additional query words: 5.00 5.00c 7.00 8.00 97

Keywords          : kbprg kbdta KbVBA 
Version           : WINDOWS:5.0,7.0,97
Platform          : WINDOWS

Last Reviewed: May 17, 1999