XL97: How to Simulate a Paused Visual Basic Procedure

ID: Q161535

The information in this article applies to:

Microsoft Excel 97 for Windows

SUMMARY

There is no built-in method for pausing a macro in Microsoft Excel. This article contains one method for stopping a macro for user input and then continuing when the user clicks a button.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/

To use this method, follow these steps:

1. Close and save any open workbooks, and then open a new workbook.

2. Start the Visual Basic Editor (press ALT+F11).

3. Click module on the Insert menu.

4. Type the following procedures into the code window for Module1.

      Sub CreatePauseToolbar()

          Dim NewBar As Object

          'Creates the toolbar, and sets a variable to easily format it
          Set NewBar = CommandBars.Add

          With NewBar

              'Sets the toolbar's name
              .Name = "Pause"

              'Makes the toolbar visible
              .Visible = True

              'Adds a button to the toolbar
              .Controls.Add Type:=msoControlButton

              With .Controls(1)

                  'Sets the style of the button to text only
                  .Style = msoButtonCaption

                  'Sets the caption of the button
                  .Caption = "Continue"

                  'Assigns the macro PartTwo to the button
                  .OnAction = "PartTwo"

              End With
          End With
      End Sub

      Sub PartOne()

          'Prompt the user to select a range
          MsgBox "Select the Border Range, then" & Chr(13) & _
              "click the Continue button."

          'Run the procedure that creates the toolbar
          CreatePauseToolbar

      End Sub

      Sub PartTwo()

          'Applies the border to the selected range
          Selection.BorderAround Weight:=xlThick

          'Deletes the Pause toolbar
          CommandBars("Pause").Delete

      End Sub

5. Click "Close and Return to Microsoft Excel" on the File menu.

6. Point to Macros on the Tools menu, then click Macros. In the Macros

   dialog box, select "PartOne", then click Run.

   The PartOne procedure prompts you to select a range of cells.

7. Click OK.

   The PartOne procedure calls the CreatePauseToolbar procedure, which
   creates the Pause toolbar and makes it visible.

8. Select a range of cells on Sheet1.

9. Click the Continue button on the Pause toolbar.

Clicking the Continue button calls the PartTwo procedure, which applies an outline border to the current selection, then deletes the Pause toolbar.

NOTE: In this example, macro execution actually ends at the end of the PartOne procedure. As a result, all procedure-level variables that have been declared in the PartOne procedure lose their values before the PartTwo procedure is executed.

REFERENCES

For additional information about the lifetime of variables, please see the following article here in the Microsoft Knowledge Base:

   ARTICLE-ID: Q141693
   TITLE     : XL: Scope of Variables in Visual Basic for Applications

For additional information about Creating a Pause Toolbar in earlier versions of Microsoft Excel, please see the following article here in the Microsoft Knowledge Base:

   ARTICLE-ID: Q131847
   TITLE     : Creating a PAUSE Button in visual Basic for Applications

For more information about cmmand bars, click the Office Assistant while in the Visual Basic Editor, type "commandbars," click Search, and then click to view "Using command bars."

Additional query words: 97 8.00 XL97 command bar

Keywords          : kbprg kbui kbdta kbdtacode xlui KbVBA 
Version           : WINDOWS:97
Platform          : WINDOWS
Issue type        : kbhowto

Last Reviewed: May 18, 1999