VB3 Scrolling Text Box Programmatically and Specifing Lines

ID: Q73371

The information in this article applies to:

Microsoft Visual Basic Standard and Professional Editions for Windows, versions 2.0, 3.0
Microsoft Visual Basic programming system for Windows, version 1.0

SUMMARY

By making a call to the Windows API function SendMessage, you can scroll text a specified number of lines or columns within a Microsoft Visual Basic for Windows text box. By using SendMessage, you can also scroll text programmatically, without user interaction. This technique extends Visual Basic for Windows' scrolling functionality beyond the built-in statements and methods. The sample program below shows how to scroll text vertically and horizontally a specified number of lines.

MORE INFORMATION

Visual Basic for Windows itself does not offer a statement for scrolling text a specified number of lines vertically or horizontally within a text box. You can scroll text vertically or horizontally by actively clicking the vertical and horizontal scroll bars for the text box at run time; however, you do not have any control over how many lines or columns are scrolled for each click of the scroll bar. Text always scrolls one line or one column per click the scroll bar. Furthermore, no built-in Visual Basic for Windows method can scroll text without user interaction. To work around these limitations, you can call the Windows API function SendMessage, as explained below.

Example

To scroll the text a specified number of lines within a text box requires a call to the Windows API function SendMessage using the constant EM_LINESCROLL. You can invoke the SendMessage function from Visual Basic for Windows as follows:


r& = SendMessage& (hWd%, EM_LINESCROLL, wParam%, lParam&)

     hWd%     The window handle of the text box.
     wParam%  Parameter not used.
     lParam&  The low-order 2 bytes specify the number of vertical
              lines to scroll. The high-order 2 bytes specify the
              number of horizontal columns to scroll. A positive
              value for lParam& causes text to scroll upward or to the
              left. A negative value causes text to scroll downward or
              to the right.
     r&       Indicates the number of lines actually scrolled.

The SendMessage API function requires the window handle (hWd% above) of the text box. To get the window handle of the text box, you must first set the focus on the text box using the SetFocus method from Visual Basic. Once the focus has been set, call the GetFocus API function to get the window handle for the text box. Below is an example of how to get the window handle of a text box.


     ' The following appears in the general declarations section of
     ' the form:
     Declare Function GetFocus% Lib "USER" ()

     ' Assume the following appears in the click event procedure of a
     ' command button called Scroll.
     Sub Command_Scroll_Click ()
          OldhWnd% =  Screen.ActiveControl.Hwnd
          ' Store the window handle of the control that currently
          ' has the focus.

          ' For Visual Basic 1.0 for Windows use the following line:
          ' OldhWnd% =  GetFocus ()

          Text1.SetFocus
          hWd% = GetFocus()
     End Sub

To scroll text horizontally, the text box must have a horizontal scroll bar, and the width of the text must be wider than the text box width. Calling SendMessage to scroll text vertically does not require a vertical scroll bar, but the length of text within the text box should exceed the text box height.

Below are the steps necessary to create a text box that will scroll five vertical lines or five horizontal columns each time you click the command buttons labeled "Vertical" and "Horizontal":

From the File menu, choose New Project (press ALT, F, N).

Double-click Form1 to bring up the code window.

Add the following API declaration to the General Declarations section of Form1. Note that you must put all Declare statements on a separate and single line. Also note that SetFocus is aliased as PutFocus because there already exists a SetFocus method within Visual Basic for Windows.


    Declare Function GetFocus% Lib "user" () ' For Visual Basic 1.0 only.
    Declare Function PutFocus% Lib "user" Alias "SetFocus" (ByVal
                                                           hWd%)
    Declare Function SendMessage& Lib "user" (ByVal hWd%,
                                              ByVal wMsg%,
                                              ByVal wParam%,
                                              ByVal lParam&)

Create a text box called Text1 on Form1. Set the MultiLine property to True and the ScrollBars property to Horizontal (1).

Create a command button called Command1 and change the Caption to "Vertical".

Create a another command button called Command2 and change the Caption to "Horizontal".

From the General Declarations section of Form1, create a procedure to initialize some text in the text box as follows:


    Sub InitializeTextBox ()
       Text1.Text = ""
       For i% = 1 To 50
          Text1.Text = Text1.Text + "This is line " + Str$(i%)

          ' Add 15 words to a line of text.
          For j% = 1 to 10
             Text1.Text = Text1.Text + " Word "+ Str$(j%)
          Next j%

          ' Force a carriage return (CR) and linefeed (LF).
          Text1.Text = Text1.Text + Chr$(13) + Chr$(10)

          x% = DoEvents()
       Next i%
    End Sub

Add the following code to the load event procedure of Form1:


    Sub Form_Load ()
       Call InitializeTextBox
    End Sub

Create the actual scroll procedure within the General Declarations section of Form1 as follows:


    ' The following two lines must appear on a single line:

    Function ScrollText& (TextBox As Control, vLines As Integer, hLines
                          As Integer)
       Const EM_LINESCROLL = &H406

       ' Place the number of horizontal columns to scroll in the high-
       ' order 2 bytes of Lines&. The vertical lines to scroll is
       ' placed in the low-order 2 bytes.
       Lines& = Clng(&H10000 * hLines) + vLines

       ' Get the window handle of the control that currently has the
       ' focus, Command1 or Command2.
       SavedWnd%  = Screen.ActiveControl.Hwnd
       ' For Visual Basic 1.0 use the following line instead of the one
       ' used above.
       ' SavedWnd% = GetFocus%()

       ' Set the focus to the passed control (text control).
       TextBox.SetFocus

       ' For Visual Basic 1.0, get the handle to current focus (text
       ' control).
       ' TextWnd% = GetFocus%()

       ' Scroll the lines.
       Success& = SendMessage(TextBox.HWnd, EM_LINESCROLL, 0, Lines&)
       ' For Visual Basic 1.0 use the following line instead of the one
       ' used above.
       ' Success& = SendMessage(TextWnd%, EM_LINESCROLL, 0, Lines&)

       ' Restore the focus to the original control, Command1 or
       ' Command2.
       r% = PutFocus% (SavedWnd%)

       ' Return the number of lines actually scrolled.
       ScrollText& = Success&

    End Function

Add the following code to the click event procedure of Command1 labeled "Vertical":


    Sub Command1_Click ()
       ' Scroll text 5 vertical lines upward.
       Num& = ScrollText&(Text1, 5, 0)
    End Sub

Add the following code to the click event procedure of Command2 labeled "Horizontal":


     Sub Command2_Click ()
         ' Scroll text 5 horizontal columns to the left.
         Num& = ScrollText&(Text1, 0, 5)
     End Sub

Run the program. Click the command buttons to scroll the text five lines or columns at a time.

Additional query words: 2.00 3.00


Keywords          : kbcode kbWndw PrgCtrlsStd 
Version           : 1.00 2.00 3.00
Platform          : WINDOWS 
Issue type        :

Last Reviewed: June 22, 1999