Symbol Characters Change to Box Characters

• Microsoft Word 97 for Windows

SYMPTOMS

When you format text with a symbol font, such as Wingdings, and then change to a non-symbol font such as Times New Roman, the text is replaced with box characters.

CAUSE

Word displays the box characters after it translates the symbol font to its Unicode equivalent.

This problem occurs when you do the following:

1. Format text using a symbol font, such as Wingdings.



2. Select the text from Step 1 and apply a non-symbol font, such as Times New Roman.

WORKAROUND

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Solution Provider or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Solution Providers, please see the following page on the World Wide Web:

http://www.microsoft.com/isapi/referral/obtain_servicesBasic.asp

http://www.microsoft.com/support/supportnet/refguide/

Sub ConvertSymbol()
   Dim dlg As Object
   Dim NoFC As Integer
   Dim SCP As Integer
   Dim StartRange As Range
   Dim UniCodeNum As Integer
   ' Temporarily disable Screen Updating
   Application.ScreenUpdating = False
   ' Temporarily disable Smart Cut & Paste
   If Options.SmartCutPaste = True Then
      SCP = 1
      Options.SmartCutPaste = False
   End If
   ' Temporarily display field text
   If ActiveWindow.View.ShowFieldCodes = False Then
      NoFC = 1
      ActiveWindow.View.ShowFieldCodes = True
   End If
   ' Set StartRange variable to current selection's range
   Set StartRange = Selection.Range
   Selection.Collapse
   ' Select first, then each next character in user-defined selection
   Selection.MoveRight unit:=wdCharacter, Extend:=wdExtend
   While Selection.End <= StartRange.End And _
   ActiveDocument.Content.End > Selection.End
     ' If the character is a space, then move to next character
     Set dlg = Dialogs(wdDialogInsertSymbol)
     UniCodeNum = dlg.charnum
     If UniCodeNum = 32 Then
       Selection.Collapse
       Selection.MoveRight unit:=wdCharacter, Extend:=wdMove
       Selection.MoveRight unit:=wdCharacter, Extend:=wdExtend
     End If
     ' Loop, converting symbol Unicode characters to ASCII characters
     Set dlg = Dialogs(wdDialogInsertSymbol)
     UniCodeNum = dlg.charnum
     While UniCodeNum < 0 And Selection.End <= StartRange.End _
     And ActiveDocument.Content.End > Selection.End
        Selection.Delete
        Selection.InsertAfter (ChrW(UniCodeNum + 4096))
        Selection.Collapse (wdCollapseEnd)
        Selection.MoveRight unit:=wdCharacter, Extend:=wdExtend
        Set dlg = Dialogs(wdDialogInsertSymbol)
        UniCodeNum = dlg.charnum
     Wend
     Selection.Collapse (wdCollapseEnd)
     Selection.MoveRight unit:=wdCharacter, Extend:=wdExtend
   Wend
   ' Reset Word document settings
   If SCP = 1 Then Options.SmartCutPaste = True
   If NoFC = 1 Then ActiveWindow.View.ShowFieldCodes = False
      Selection.Collapse (wdCollapseStart)
      Selection.MoveLeft unit:=wdCharacter
      Application.ScreenUpdating = True
End Sub 

MORE INFORMATION

The following table lists common symbol and non-symbol fonts.

   Symbol Fonts                             Non-Symbol Fonts
   ---------------------------------------------------------
   Bookshelf Symbol 3                       Arial
   Marlett                                  Book Antiqua
   Monotype Sorts                           Bookman Old Style
   MS Outlook                               Century Schoolbook
   MT Extra                                 Courier New
   Symbol                                   Garamond
   Wingdings                                Times New Roman 

Unicode

Additional query words: square boxed garbage incorrect font symbols change changed changing boxes

Keywords          : kbdta kbdtacode kbwordvba word97 
Version           : WINDOWS:97
Platform          : WINDOWS 
Issue type        : kbprb 

Last Reviewed: April 29, 1999