HOWTO: Send Raw Data to a Printer Using the Win32 API from Visual Basic

• Microsoft Visual Basic Learning, Professional, and Enterprise Editions for Windows, version 6.0
• Microsoft Visual Basic Standard, Professional, and Enterprise Editions, 32-bit only, for Windows, version 4.0

SUMMARY

Although the printer object under Visual Basic 4.0 has been greatly improved, there may still be times when it is desirable to use the Win 32 API to send information directly to the printer. Below is a code sample showing how to achieve this behavior.

MORE INFORMATION

1. Start a new project in Visual Basic. Form1 is created by default.



2. Place a Command Button on the form.



3. Add the following code to the Form1 code window:
   

   
         Option Explicit
   
         Private Type DOCINFO
             pDocName As String
             pOutputFile As String
             pDatatype As String
         End Type
   
         Private Declare Function ClosePrinter Lib "winspool.drv" (ByVal _
            hPrinter As Long) As Long
         Private Declare Function EndDocPrinter Lib "winspool.drv" (ByVal _
            hPrinter As Long) As Long
         Private Declare Function EndPagePrinter Lib "winspool.drv" (ByVal _
            hPrinter As Long) As Long
         Private Declare Function OpenPrinter Lib "winspool.drv" Alias _
            "OpenPrinterA" (ByVal pPrinterName As String, phPrinter As Long, _
             ByVal pDefault As Long) As Long
         Private Declare Function StartDocPrinter Lib "winspool.drv" Alias _
            "StartDocPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
            pDocInfo As DOCINFO) As Long
         Private Declare Function StartPagePrinter Lib "winspool.drv" (ByVal _
            hPrinter As Long) As Long
         Private Declare Function WritePrinter Lib "winspool.drv" (ByVal _
            hPrinter As Long, pBuf As Any, ByVal cdBuf As Long,  _
            pcWritten As Long) As Long
   
         Private Sub Command1_Click()
             Dim lhPrinter As Long
             Dim lReturn As Long
             Dim lpcWritten As Long
             Dim lDoc As Long
             Dim sWrittenData As String
             Dim MyDocInfo As DOCINFO
             lReturn = OpenPrinter("Call Screener Printer", lhPrinter, 0)
             If lReturn = 0 Then
                 MsgBox "The Printer Name you typed wasn't recognized."
                 Exit Sub
             End If
             MyDocInfo.pDocName = "AAAAAA"
             MyDocInfo.pOutputFile = vbNullString
             MyDocInfo.pDatatype = vbNullString
             lDoc = StartDocPrinter(lhPrinter, 1, MyDocInfo)
             Call StartPagePrinter(lhPrinter)
             sWrittenData = "How's that for Magic !!!!" & vbFormFeed
             lReturn = WritePrinter(lhPrinter, ByVal sWrittenData, _
                Len(sWrittenData), lpcWritten)
             lReturn = EndPagePrinter(lhPrinter)
             lReturn = EndDocPrinter(lhPrinter)
             lReturn = ClosePrinter(lhPrinter)
         End Sub
    

REFERENCES

The Win32 SDK Help files give a more detailed description of the APIs used in the sample.

For information on the same procedure for VC++, please see the following article in the Microsoft Knowledge Base:

Q138594 : HOWTO: Send Raw Data to a Printer by Using the Win32 API

Additional query words: raw receipt

Keywords          : kbAPI kbPrinting kbVBp400 kbVBp600 
Version           : WINDOWS:4.0,6.0
Platform          : WINDOWS 
Issue type        : kbhowto 

Last Reviewed: May 13, 1999