ACC: FileCopy Statement May Not Copy Open Files

ID: Q172711


The information in this article applies to:


SYMPTOMS

Advanced: Requires expert coding, interoperability, and multiuser skills.

When you programmatically copy a file with the FileCopy statement in Visual Basic for Applications, you may receive the following error message:

Run-time error '70'

Permission denied

This article assumes that you are familiar with Visual Basic for Applications and with creating Microsoft Access applications using the programming tools provided with Microsoft Access. For more information about Visual Basic for Applications, please refer to your version of the "Building Applications with Microsoft Access" manual.


CAUSE

The file is currently open, which prevents the FileCopy statement from copying the file.


RESOLUTION

Instead of using the FileCopy statement, use one of the following methods to programmatically copy the file.

WARNING: The following functions enable you to copy an open file. If the source file is changed while the copy operation is in process, the destination file may be incomplete or may become corrupted.

Method 1 - Calling the CopyFile() function from the Windows API

One method to programmatically copy a file is to call the CopyFile() function from the Microsoft Windows API. To call the CopyFile() function from the Microsoft Windows API, follow these steps:
  1. Complete steps 1 through 4 from the "Steps to Reproduce Behavior" section later in this article.


  2. Create a module and type the following lines in the Declarations section:
    
          Option Explicit 
    
          Declare Function apiCopyFile Lib "kernel32" Alias "CopyFileA" _
          (ByVal lpExistingFileName As String, _
          ByVal lpNewFileName As String, _
          ByVal bFailIfExists As Long) As Long 


  3. Type the following procedure:
    
          Sub CopyFile(SourceFile As String, DestFile As String)
          '---------------------------------------------------------------
          ' PURPOSE: Copy a file on disk from one location to another.
          ' ACCEPTS: The name of the source file and destination file.
          ' RETURNS: Nothing
          '---------------------------------------------------------------
            Dim Result As Long
             If Dir(SourceFile) = "" Then
                MsgBox Chr(34) & SourceFile & Chr(34) & _
                   " is not valid file name."
             Else
                Result = apiCopyFile(SourceFile, DestFile, False)
             End If
          End Sub 


  4. To test this procedure, type the following line in the Debug window, and then press ENTER:

    CopyFile "<path to Northwind.mdb>", "C:\Northwind.mdb"

    Note that Northwind.mdb is copied to the root folder of drive C, even though it is currently open in another instance of Microsoft Access.


Method 2 - Calling the MS-DOS Copy Command

Another method to programmatically copy a file is to call the MS-DOS Copy command from a Shell() function in Visual Basic for Applications. To call the MS-DOS Copy command, follow these steps:
  1. Complete steps 1 through 4 from the "Steps to Reproduce Behavior" section later in this article.


  2. Create a module and type the following line in the Declarations section if it is not already there:
    
          Option Explicit 


  3. If you are using Microsoft Windows 95, type the following procedure:
    
          Sub CopyFile(SourceFile As String, DestFile As String)
          '---------------------------------------------------------------
          ' PURPOSE: Copy a file on disk from one location to another.
          ' ACCEPTS: The name of the source file and destination file.
          ' RETURNS: Nothing
          '---------------------------------------------------------------
             Dim CopyString As String
             If Dir(SourceFile) = "" Then
                MsgBox Chr(34) & SourceFile & Chr(34) & _
                   " is not a valid file name."
             Else
                SourceFile = Chr(34) & SourceFile & Chr(34)
                DestFile = Chr(34) & DestFile & Chr(34)
                CopyString = "COMMAND.COM /C COPY " & SourceFile & _
                   " " & DestFile
                Call Shell(CopyString, 0)
             End If
          End Sub
    
       If you are using Microsoft Windows NT, use the same procedure, but
       change the line
    
          CopyString = "COMMAND.COM /C COPY " & SourceFile & _
    
       to:
    
          CopyString = "CMD.EXE /C COPY " & SourceFile & _ 


  4. To test this procedure, type the following line in the Debug window, and then press ENTER:

    CopyFile "<path to Northwind.mdb>", "C:\Northwind.mdb"

    Note that Northwind.mdb is copied to the root folder of drive C, even though it is currently open in another instance of Microsoft Access.



STATUS

This behavior is by design.


MORE INFORMATION

Steps to Reproduce Behavior


  1. Start Microsoft Access.


  2. Open the sample database Northwind.mdb.


  3. Start a new instance of Microsoft Access.


  4. Create a new blank database.


  5. Create a module and type the following line in the Declarations section if it is not already there:
    
          Option Explicit 


  6. Type the following procedure:
    
          Sub CopyFile(SourceFile As String, DestFile As String)
             FileCopy SourceFile, DestFile
          End Sub 


  7. To test this procedure, type the following line in the Debug window, and then press ENTER:

    CopyFile "<path to Northwind.mdb>", "C:\Northwind.mdb"

    Note that you receive the error listed in the "Symptoms" section.



REFERENCES

For more information about the FileCopy statement, search the Help Index for "FileCopy statement."

Additional query words: file copy


Keywords          : kbprg MdlGnrl 
Version           : WINDOWS:7.0,97
Platform          : WINDOWS 
Issue type        : kbprb 

Last Reviewed: April 19, 1999